home *** CD-ROM | disk | FTP | other *** search
/ westlife Cardz: Kian / westlife: Kian.iso / pc / trivia.dxr / 00001_Trivia Game Frame Behavior.ls next >
Encoding:
Text File  |  2000-10-23  |  2.0 KB  |  83 lines
  1. property pDataMember, pQuestionNum, pPossiblePoints, pScore, pCorrectAnswer, pCorrectSound, pWrongSound, pEndGameFrame
  2.  
  3. on getPropertyDescriptionList me
  4.   list = [:]
  5.   addProp(list, #pDataMember, [#comment: "Data Member", #format: #text, #default: VOID])
  6.   addProp(list, #pCorrectSound, [#comment: "Correct Sound", #format: #string, #default: EMPTY])
  7.   addProp(list, #pWrongSound, [#comment: "Wrong Sound", #format: #string, #default: EMPTY])
  8.   addProp(list, #pEndGameFrame, [#comment: "End Game Frame", #format: #marker, #default: #next])
  9.   return list
  10. end
  11.  
  12. on beginSprite me
  13.   pQuestionNum = 1
  14.   pScore = 0
  15.   showScore(me)
  16.   askQuestion(me)
  17. end
  18.  
  19. on askQuestion me
  20.   text = pDataMember.text.line[pQuestionNum]
  21.   sendAllSprites(#makeVisible)
  22.   the itemDelimiter = ";"
  23.   question = text.item[1]
  24.   answers = text.item[2]
  25.   pCorrectAnswer = value(text.item[3])
  26.   member("Question").text = question
  27.   the itemDelimiter = ","
  28.   repeat with i = 1 to 4
  29.     member("Answer" && i).text = answers.item[i]
  30.   end repeat
  31.   pPossiblePoints = 1000
  32.   showPossiblePoints(me)
  33. end
  34.  
  35. on showPossiblePoints me
  36.   if pPossiblePoints < 0 then
  37.     pPossiblePoints = 0
  38.   end if
  39.   member("Possible Points").text = "Points:" && pPossiblePoints
  40. end
  41.  
  42. on showScore me
  43.   member("Score").text = "Score:" && pScore
  44. end
  45.  
  46. on clickAnswer me, n
  47.   if n = pCorrectAnswer then
  48.     if pCorrectSound <> EMPTY then
  49.       puppetSound(pCorrectSound)
  50.     end if
  51.     pScore = pScore + pPossiblePoints
  52.     showScore(me)
  53.     nextQuestion(me)
  54.     return 1
  55.   else
  56.     if pWrongSound <> EMPTY then
  57.       puppetSound(pWrongSound)
  58.     end if
  59.     pPossiblePoints = pPossiblePoints - 100
  60.     showPossiblePoints(me)
  61.     return 0
  62.   end if
  63. end
  64.  
  65. on nextQuestion me
  66.   pQuestionNum = pQuestionNum + 1
  67.   if pQuestionNum > pDataMember.text.line.count then
  68.     go(pEndGameFrame)
  69.   else
  70.     askQuestion(me)
  71.   end if
  72. end
  73.  
  74. on exitFrame me
  75.   pPossiblePoints = pPossiblePoints - 1
  76.   showPossiblePoints(me)
  77.   go(the frame)
  78. end
  79.  
  80. on keyDown me
  81.   sendAllSprites(#keyHit, the key)
  82. end
  83.